발주관리#6 매입처 추가(등록)

이번 포스팅은 지난 발주관리#3에서 만들어둔 버튼에 프로시저를 만들어 연결하겠습니다.

지난 포스팅에서 만들었던 유저관리폼과 함께 사용하게 됩니다.

 

우선 추가버튼에 연결할 프로시저를 만듭니다.

'매입처등록폼 불러오기
Public Sub show_매입처등록폼()
 
    With 매입처등록폼
        .StartUpPosition = 0
        .Left = 400
        .Top = 200
        .Show                   '매입처등록폼 불러오기
    End With
 
End Sub

 

추가버튼에 매크로 연결을 해주세요.

 

이제 매입처등록폼에 내용을 채워줘야 합니다.

좌측 프로젝트창에서 폼>매입처등록폼을 우클릭 한뒤 코드보기를 눌러주세요.

 

매입처등록폼에 아래의 코드를 입력해 줍니다.

Option Explicit
 
'취소 버튼 클릭
Private Sub ComCancel_Click()
    
    Unload 매입처등록폼
 
End Sub
 
'저장 버튼 클릭
Private Sub ComOK_Click()
    
    On Error Resume Next
   Call DataBase연결
    
    '중복 매입처 체크
    SQL = "SELECT 매입처명 FROM 매입처 WHERE 매입처명='" & TextBox1.Value & "'"
    
    rs.CursorLocation = adUseClient
    rs.Open SQL, Cn, adOpenStatic, adLockReadOnly
    
    If rs.RecordCount > 0 Then
        MsgBox "이미 등록되어있는 매입처 입니다.", vbCritical, "오류"
        rs.Close
        Cn.Close
        Exit Sub
    Else
        rs.Close
    End If
    
    '매입처 추가 SQL문
    SQL = "INSERT INTO 매입처 (매입처명, 구분) VALUES ('" & TextBox1.Value & "', '" & ComboBox1.Value & "')"
    
    rs.Open SQL, Cn
    rs.Close
    Cn.Close
    
    Unload 매입처등록폼
    Call 매입처DB불러오기
 
End Sub
 
'유저폼 열릴때 실행
Private Sub UserForm_Initialize()
 
    Dim i As Integer
    
   Call DataBase연결
    
    SQL = "SELECT 구분 FROM 매입처 GROUP BY 구분"
 
    rs.CursorLocation = adUseClient
    rs.Open SQL, Cn, adOpenStatic, adLockReadOnly
 
    For i = 0 To (rs.RecordCount - 1)
        매입처등록폼.ComboBox1.AddItem rs.Fields("구분")
        rs.MoveNext
    Next i
    rs.Close
    Cn.Close
    
    ComboBox1.ListIndex = 0
 
End Sub

 

총 3개의 프로시저를 만들었습니다.

취소버튼 클릭시, 저장버튼 클릭시, 유저폼 열릴때 각각 실행되는 프로시저들 입니다.

 

우선 취소버튼은 간단하게 눌렀을때 유저폼을 닫아주는 역할만 합니다.

 

저장버튼은 눌렀을때 데이터베이스에 같은 매입처가 있는지 체크한후 있을 경우에는 msgbox로 경고메세지를,

없을 경우에는 insert into 구문으로 DB에 매입처를 추가해 줍니다.

 

그리고 유저폼이 열렸을때 실행되는 프로시저는 DB에서 구분 필드를 불러와 combobox에 additem 시켜줍니다.

 

거래처 추가에 대한 내용은 여기까지입니다.

다음 포스팅은 거래처 수정쪽을 만들어 보도록 하겠습니다.